Laboratorio Ejemplo de IXP con Miktrotik

[josemiguel]

Se pretende llegar al siguiente diagrama

Tabla de Ayuda

1 Importar laboratorio de EVE-NG

_Exports_unetlab_export-20250410-230447.zip

2 Poner los Scripts en los Router

Facebook

#

/routing bgp instance set default as=100

#

/ip address

add address=1.1.1.1/24 comment=to-Cirion interface=ether5 network=1.1.1.0

add address=7.7.7.2/24 comment=to-Server-Facebook interface=ether2 network=7.7.7.0

#

/routing bgp network add network=7.7.7.0/24 synchronize=no

#

/routing bgp peer add name=peer-to-cirion remote-address=1.1.1.2 remote-as=1100

#

/system identity set name=Facebook

/tool romon set enabled=yes

Cirion Carrier

#

/routing bgp instance set default as=1100 redistribute-connected=yes

#

/ip address

add address=2.2.2.2/24 comment=to-Google interface=ether3 network=2.2.2.0

add address=5.5.5.1/24 comment=to-ISP-TotalPlay interface=ether2 network=5.5.5.0

add address=1.1.1.2/24 comment=to-Facebook interface=ether5 network=1.1.1.0

add address=12.12.12.2/24 comment=to-Alestra interface=ether4 network=12.12.12.0

#

/routing bgp peer

add name=peer-to-google remote-address=2.2.2.1 remote-as=200

add name=peer-to-isp-borde-totalplay remote-address=5.5.5.2 remote-as=500

add name=peer-to-facebook remote-address=1.1.1.1 remote-as=100

add name=peer-to-alestra remote-address=12.12.12.1 remote-as=300

#

/system identity set name=Cirion

/tool romon set enabled=yes

Google

#

/routing bgp instance set default as=200

#

/ip address

add address=2.2.2.1/24 comment=to-TotalPlay interface=ether3 network=2.2.2.0

add address=8.8.8.2/24 comment=to-Server-Google interface=ether2 network=8.8.8.0

#

/routing bgp network add network=8.8.8.0/24 synchronize=no

#

/routing bgp peer

add name=peer-to-alestra remote-address=2.2.2.2 remote-as=1100

#

/system identity set name=Google

/tool romon set enabled=yes

Alestra Carrier

#

/routing bgp instance set default as=300 redistribute-connected=yes

#

/ip address

add address=3.3.3.1/24 comment=to-ISP-Borde-Intercun interface=ether3 network=3.3.3.0

add address=12.12.12.1/24 comment=to-Cirion-Carrier interface=ether4 network=12.12.12.0

#

/routing bgp peer

add name=peer-to-isp-borde-intercun remote-address=3.3.3.2 remote-as=400

add name=peer-to-cirion-carrier remote-address=12.12.12.2 remote-as=1100

#

/system identity set name=Alestra

/tool romon set enabled=yes

ISP-Borde-Intercun

#

/routing bgp instance set default as=400

#

/ip address

add address=3.3.3.2/24 comment=to-Alestra-Carrier interface=ether1 network=3.3.3.0

add address=4.4.5.254/24 comment=to-ISP-Core-Interncun interface=ether2 network=4.4.5.0

add address=10.10.10.2/24 comment=to-IXP interface=ether3 network=10.10.10.0

#

/routing bgp network

add network=4.4.4.0/24 synchronize=no

add network=4.4.5.0/24 synchronize=no

#

/routing bgp peer

add name=peer-to-alestra-carrier remote-address=3.3.3.1 remote-as=300

add name=peer-to-ixp remote-address=10.10.10.1 remote-as=1000

#

/system identity set name=ISP-Borde-Intercun

/tool romon set enabled=yes

IXP

#

/interface bridge add name=bridge-isps

#

/routing bgp instance set default as=1000 redistribute-connected=yes

#

/interface bridge port

add bridge=bridge-isps interface=ether3

add bridge=bridge-isps interface=ether4



#

/ip address

add address=10.10.10.1/24 comment=to-ISPs interface=bridge-isps network=10.10.10.0

add address=9.9.9.1/29 comment=to-Facebook-CDN interface=ether5 network=9.9.9.0

add address=9.9.9.9/29 comment=to-Google-CDN interface=ether6 network=9.9.9.8

#

/routing bgp network

add network=10.10.10.0/24 synchronize=no

#

/routing bgp peer

add name=peer-to-intercun remote-address=10.10.10.2 remote-as=400

add name=peer-to-facebook-cdn remote-address=9.9.9.2 remote-as=100

add name=peer-to-google-cdn remote-address=9.9.9.10 remote-as=200

add name=peer-to-totalplay remote-address=10.10.10.3 remote-as=500

#

/system identity set name=IXP

/tool romon set enabled=yes

Facebook CDN

#

/routing bgp instance set default as=100

#

/ip address

add address=9.9.9.2/29 comment=to-IXP interface=ether2 network=9.9.9.0

add address=7.7.7.2/24 comment=to-Server interface=ether3 network=7.7.7.0

#

/routing bgp network add network=7.7.7.0/24 synchronize=no

#

/routing bgp peer add name=peer-to-ixp remote-address=9.9.9.1 remote-as=1000

#

/system identity set name=Facebook-CDN

/tool romon set enabled=yes

Google CDN

#

/routing bgp instance set default as=200

#

/ip address

add address=8.8.8.2/24 comment=to-Server interface=ether3 network=8.8.8.0

add address=9.9.9.10/29 comment=to-IXP interface=ether6 network=9.9.9.8

#

/routing bgp network add network=8.8.8.0/24 synchronize=no

#

/routing bgp peer add name=peer-to-ixp remote-address=9.9.9.9 remote-as=1000

#

/system identity set name=Google-CDN

/tool romon set enabled=yes

ISP-Borde-TotalPlay

#

/routing bgp instance set default as=500

#

/ip address

add address=5.5.5.2/24 comment=to-Cirion interface=ether2 network=5.5.5.0

add address=11.11.12.254/24 comment=to-ISP-Core-TotalPlay interface=ether3 network=11.11.12.0

add address=10.10.10.3/24 comment=to-IXP interface=ether4 network=10.10.10.0

#

/routing bgp network

add network=11.11.11.0/24 synchronize=no

add network=11.11.12.0/24 synchronize=no

#

/routing bgp peer

add in-filter=ruta-larga name=peer-to-cirion remote-address=5.5.5.1 remote-as=1100

add name=peer-to-ixp remote-address=10.10.10.1 remote-as=1000

#

/routing filter add action=accept chain=ruta-larga set-bgp-prepend-path=2



#

/system identity set name=ISP-Borde-TotalPlay

/tool romon set enabled=yes

ISP-Core-Intercun

#

/ip address

add address=4.4.5.2/24 comment=to-ISP-Borde-Intercun interface=ether1 network=4.4.5.0

add address=192.168.9.254/24 comment=to-Cliente-Final-Intercun interface=ether8 network=192.168.9.0

#

/ip firewall nat add action=masquerade chain=srcnat out-interface=ether1



#

/ip route add distance=1 gateway=4.4.5.254



#

/system identity set name=ISP-Core-Intercun

/tool romon set enabled=yes

ISP-Core-TotalPlay

#

/ip address

add address=11.11.12.2/24 comment=to-ISP-Borde-TotalPlay interface=ether3 network=11.11.12.0

add address=192.168.11.254/24 comment=to-Cliente-Final-TotalPlay interface=ether2 network=192.168.11.0



#

/ip firewall nat add action=masquerade chain=srcnat



#

/ip route add distance=1 gateway=11.11.12.254



#

/system identity set name=ISP-Core-TotalPlay

/tool romon set enabled=yes

3 Pruebas

Traceroute a Facebook y Google en Cliente Final Intercun, se debe ir a Facebook-CDN y Google-CDN pasando por el IXP

As Path de ISP-Borde-Intercun

Traceroute a Facebook y Google en Cliente Final TotalPlay, se debe ir a Facebook-CDN y Google-CDN pasando por el IXP

As Path de ISP-Borde-TotalPlay

Se apagan las interfaces de Facebook-CDN y Google-CDN en el IXP

Traceroute a Facebook y Google en Cliente Final Intercun, se debe ir a Facebook y Google sin pasar por el IXP porque las interfaces ya están apagadas.

As Path de ISP-Borde-Intercun con las interfaces apagadas de los CDNs en el IXP.

Traceroute a Facebook y Google en Cliente Final TotalPlay, se debe ir a Facebook y Google sin pasar por el IXP porque las interfaces ya están apagadas.

As Path de ISP-Borde-TotalPlay con las interfaces apagadas de los CDNs en el IXP.