Se pretende llegar al siguiente diagrama
Archivo adjunto 4037
1 Importar laboratorio de EVE-NG
Archivo adjunto 4038
2 Poner los Scripts en los Router
Google
#
/routing bgp instance set default as=15169
#
/ip address
add address=2.2.2.2/24 comment=to-Liberty interface=ether2 network=2.2.2.0
add address=8.8.8.2/24 comment=to-Server-Google interface=ether4 network=8.8.8.0
add address=3.3.3.2/24 comment=to-Alestra interface=ether3 network=3.3.3.0
#
/routing bgp network add network=8.8.8.0/24 synchronize=no
#
/routing bgp peer
add name=peer-to-liberty remote-address=2.2.2.1 remote-as=6830
add name=peer-to-alestra remote-address=3.3.3.1 remote-as=11172
#
/system identity set name=Google
/tool romon set enabled=yes
Liberty
#
/routing bgp instance set default as=6830 redistribute-connected=yes
#
/ip address
add address=2.2.2.1/24 comment=to-Google interface=ether2 network=2.2.2.0
add address=4.4.4.1/24 comment=to-ISP-2 interface=ether3 network=4.4.4.0
#
/routing bgp peer
add name=peer-to-google remote-address=2.2.2.2 remote-as=15169
add name=peer-to-isp-2 remote-address=4.4.4.2 remote-as=265580
#
/system identity set name=Liberty
/tool romon set enabled=yes
ISP-2
#
/routing bgp instance set default as=265580 redistribute-connected=yes
#
/ip address
add address=4.4.4.2/24 comment=to-Liberty interface=ether3 network=4.4.4.0
add address=5.5.5.1/24 comment=to-Alestra interface=ether4 network=5.5.5.0
add address=10.30.24.1/30 comment=to-Borde-Megabit interface=ether2 network=10.30.24.0
#
/routing bgp peer
add name=peer-to-Liberty remote-address=4.4.4.1 remote-as=6830
add name=peer-to-Alestra remote-address=5.5.5.2 remote-as=11172
add name=peer-to-Borde-Megabit remote-address=10.30.24.2 remote-as=270200
#
/system identity set name=ISP-2
/tool romon set enabled=yes
Alestra
#
/routing bgp instance set default as=11172 redistribute-connected=yes
#
/ip address
add address=3.3.3.1/24 comment=to-Google interface=ether3 network=3.3.3.0
add address=5.5.5.2/24 comment=to-ISP-2 interface=ether4 network=5.5.5.0
add address=200.94.121.254/30 comment=to-Borde-Megabit interface=ether2 network=200.94.121.252
#
/routing bgp peer
add name=peer-to-google remote-address=3.3.3.2 remote-as=15169
add name=peer-to-ISP-2 remote-address=5.5.5.1 remote-as=265580
add name=peer-to-Borde-Megabit remote-address=200.94.121.253 remote-as=270200
#
/system identity set name=Alestra
/tool romon set enabled=yes
Borde-Megabit
#
/routing bgp instance set default as=270200 redistribute-connected=yes
#
/ip address
add address=200.94.121.253/30 comment=to-Alestra interface=ether3 network=200.94.121.252
add address=192.168.65.2/29 comment=to-isp-borde-wisphub interface=ether4 network=192.168.65.0
add address=10.30.24.2/30 comment=to-ISP-2 interface=ether2 network=10.30.24.0
add address=190.93.109.1/24 comment=to-Core-Megabit interface=ether6 network=190.93.109.0
add address=10.10.10.2/24 comment=to-Intercun interface=ether5 network=10.10.10.0
#
/routing bgp network add network=190.93.109.0/24
#
/routing bgp peer
add in-filter=ruta_larga name=peer-to-Alestra remote-address=200.94.121.254 remote-as=11172
add name=peer-to-isp-borde-wisphub remote-address=192.168.65.1 remote-as=272314
add name=peer-to-ISP-2 remote-address=10.30.24.1 remote-as=265580
add name=peer-to-Intercun remote-address=10.10.10.1 remote-as=1000
#
/routing filter add action=accept chain=ruta_larga set-bgp-prepend=2
#
/system identity set name=Borde-Megabit
/tool romon set enabled=yes
WispHub
#
/routing bgp instance set default as=272314
#
/ip address
add address=192.168.90.1/29 comment=to-isp-core-wisphub interface=ether1 network=192.168.90.0
add address=10.10.10.3/24 comment=to-ixp interface=ether2 network=10.10.10.0
add address=192.168.65.1/29 comment=to-isp-borde-megabit interface=ether4 network=192.168.65.0
#
/routing bgp network
add network=192.168.90.0/29
add network=192.168.65.0/29
#
/routing bgp peer
add name=peer_to_ixp remote-address=10.10.10.1 remote-as=1000
add name=peer_to_megabit remote-address=192.168.65.2 remote-as=270200
#
/system identity set name=WispHub
/tool romon set enabled=yes
Intercun
#
#
/interface bridge add name=bridge-to-bordes
#
/routing bgp instance set default as=1000 redistribute-connected=yes
#
/interface bridge port
add bridge=bridge-to-bordes interface=ether2
add bridge=bridge-to-bordes interface=ether3
#
/ip address
add address=10.10.10.1/24 comment=Bordes-ISP interface=bridge-to-bordes network=10.10.10.0
add address=9.9.9.1/29 comment=to-CDN-Google disabled=yes interface=ether4 network=9.9.9.0
#
/routing bgp peer
add name=peer-to-borde-wisphub remote-address=10.10.10.3 remote-as=272314
add name=peer-cdn-google remote-address=9.9.9.2 remote-as=15169
add name=peer-to-Borde-Megabit remote-address=10.10.10.2 remote-as=270200
/system identity
#
/system identity set name=Intercun
/tool romon set enabled=yes
CDN-Google
#
/routing bgp instance set default as=15169
#
/ip address
add address=9.9.9.2/29 comment=to-intercun interface=ether4 network=9.9.9.0
add address=8.8.8.2/24 comment="RED CDN" interface=ether2 network=8.8.8.0
#
/routing bgp network add network=8.8.8.0/24
#
/routing bgp peer
add name=peer-to-intercun remote-address=9.9.9.1 remote-as=1000
#
/system identity set name=CDN-Google
/tool romon set enabled=yes
Core-Megabit
#
/ip address
add address=190.93.109.2/24 comment=to-Borde-Megabit interface=ether2 network=190.93.109.0
add address=192.168.40.1/24 comment=LAN-Clientes-Megabit interface=ether3 network=192.168.40.0
#
/ip firewall nat
add action=masquerade chain=srcnat out-interface=ether2
#
/ip route
add distance=1 gateway=190.93.109.1
#
/system identity set name=Core-Megabit
/tool romon set enabled=yes
Core-Wisphub
#
/ip address
add address=192.168.90.3/29 comment=to-isp-borde-wisphub interface=ether1 network=192.168.90.0
add address=192.168.50.1/24 comment=LAN interface=ether2 network=192.168.50.0
#
/ip firewall nat
add action=masquerade chain=srcnat out-interface=ether1
#
/ip route
add comment=WAN distance=1 gateway=192.168.90.1
#
/system identity set name=Core-Wisphub
/tool romon set enabled=yes
